10 REM - GUESSNUM -
20 ]SAM
40 PRINT "{clear}":PRINT :PRINT:PRINT"GUESS THE NUMBER BETWEEN 1 AND 100"
60 N=INT(99*RND(0))+1
70 SAY "GEHS DHAX NAH4MBER BIXTWIY5N WAH4N Q AEND WAHN6 /HAH4NDRIHD."
80 INPUT G
85 REM NOTE COLON IN IF-THEN STATEMENT
90 IF G>100 THEN:SAY "DHAETS MOH4R DHAEN WAHN /HAH4NDRIHD.":GOTO 80
100 IF G<1 THEN:SAY "DHAETS LEH3S DHAEN WAH5N.":GOTO 80
110 SA$="":B$=""
120 IF G<10 THEN B$="":GOTO 340
130 ON G-9 GOTO 150,160,170,180,190,200,210,220,230,240
140 GOTO 250
150 B$="TEH4N":GOTO 460
160 B$="IHLEH4VIXN":GOTO 460
170 B$="TWEH4LV":GOTO 460
180 B$="THER4TIY6N":GOTO 460
190 B$="FOH4RTIY6N":GOTO 460
200 B$="FIH4FTIY6N":GOTO 460
210 B$="SIH4KSTIY6N":GOTO 460
220 B$="SEH4VUNTIY6N":GOTO 460
230 B$="EY4TIY6N":GOTO 460
240 B$="NAY4NTIY6N":GOTO 460
250 ON INT(G/10)-1 GOTO 260,270,280,290,300,310,320,330
260 B$="TWEH4NTIY6":GOTO 340
270 B$="THER4TIY6":GOTO 340
280 B$="FOHR4TIY6":GOTO 340
290 B$="FIH4FTIY6":GOTO 340
300 B$="SIH4KSTIY6":GOTO 340
310 B$="SEH4VUNTIY6":GOTO 340
320 B$="EY4TIY6":GOTO 340
330 B$="NAY4NTIY6"
340 R=G-10*INT(G/10)
350 IF R=0 THEN 460
360 ON R GOTO 370,380,390,400,410,420,430,440,450
370 B$=B$+"WAH5N":GOTO 460
380 B$=B$+"TUW5":GOTO 460
390 B$=B$+"THRIY5":GOTO 460
400 B$=B$+"FOHR5":GOTO 460
410 B$=B$+"FAY5V":GOTO 460
420 B$=B$+"SIH5KS":GOTO 460
430 B$=B$+"SEH5VUN":GOTO 460
440 B$=B$+"EY5T":GOTO 460
450 B$=B$+"NAY5N":GOTO 460
460 IF G>N+25 THEN C$=" IHZ MAH3CH TUW5 /HAY6.":GOTO 530
470 IF G>N+5 THEN C$=" IHZ  TUW3 /HAY6.":GOTO 530
480 IF G>N THEN C$=" IHZ AH LIH3TUL TUW4 /HAY6.":GOTO 530
490 IF G<N-25 THEN C$=" IHZ MAH3CH TUW4 LAXOW.":GOTO 530
500 IF G<N-5 THEN C$=" IHZ TUW3 LAXOW.":GOTO 530
510 IF G<N THEN C$=" IHZ AH LIH3TUL TUW4 LAXOW.":GOTO 530
520 IF G=N THEN C$="? YUW3 AAR RAY2IH7T.":GOTO 530
530 SA$=B$+C$:SAY SA$
540 IF G<>N THEN 80
550 GOTO 40
