10 REM -SAYIT-
20 PRINT "{clear}":PRINT:PRINT:PRINT "DO YOU WANT {rvrs on}S{rvrs off}AM OR {rvrs on}R{rvrs off}ECITER"
30 GET A$:IF A$="" THEN 30
40 IF A$="S" OR A$="{$d3}" THEN:]SA:PRINT:PRINT:GOTO 100
50 IF A$="R" OR A$="{$d2}" THEN:]RE:PRINT:PRINT:GOTO 100
60 GOTO 30
100 PRINT "{rvrs on}SAY:{rvrs off}";
110 SA$=""
120 GET A$:IF A$="" THEN 120
122 A=ASC(A$):IF A>132 AND A<141 THEN 500
125 IF ASC(A$)=13 THEN SA$=T$:PRINT:GOTO 200
126 SA$=A$:PRINT A$;:IF ASC(A$)=20 THEN SA$="":GOTO 120
128 GET A$:IF A$="" THEN 128
130 PRINT A$;:IF ASC(A$)=13 THEN 200
140 SA$=SA$+A$
150 IF ASC(A$)=20 THEN SA$=LEFT$(SA$,LEN(SA$)-2)
160 GOTO 128
200 SAY SA$:]ERROR:PRINT:T$=SA$:GOTO 100
500 PRINT "{clear}":PRINT "  {rvrs on}CHANGE{rvrs off}":PRINT:PRINT:PRINT"  {rvrs on}R{rvrs off}ECITER/SAM{rvrs off}":PRINT
510 PRINT "  {rvrs on}P{rvrs off}ITCH":PRINT:PRINT "  {rvrs on}S{rvrs off}PEED":PRINT:PRINT "  {rvrs on}T{rvrs off}HROAT"
520 PRINT:PRINT "  {rvrs on}M{rvrs off}OUTH":PRINT:PRINT "  {rvrs on}L{rvrs off}IGHTS":PRINT
530 PRINT "  {rvrs on}E{rvrs off}ND CHANGES":PRINT:PRINT "  {rvrs on}N{rvrs off}ORMAL VOICE"
540 PRINT :PRINT "  {rvrs on}B{rvrs off}ACK TO BASIC"
600 GET A$:IF A$="" THEN 600
610 IF A$="R" OR A$="{$d2}" THEN 1000
620 IF A$="P" OR A$="{$d0}" THEN 1100
630 IF A$="S" OR A$="{$d3}" THEN 1200
640 IF A$="T" OR A$="{$d4}" THEN 1300
650 IF A$="M" OR A$="{$cd}" THEN 1400
660 IF A$="L" OR A$="{$cc}" THEN 1500
680 IF A$="E" OR A$="E" THEN PRINT "{clear}":PRINT:PRINT:GOTO 100
685 IF A$="N"OR A$="{$ce}" THEN 1600
690 IF A$="B" OR A$="{$c2}" THEN END
695 GOTO 600
1000 PRINT:PRINT "{rvrs on}S{rvrs off}AM OR {rvrs on}R{rvrs off}ECITER";
1010 GET A$:IF A$="" THEN 1010
1020 IF A$="S" OR A$="{$d3}" THEN:]SA:GOTO 500
1030 IF A$="R"OR A$="{$d2}" THEN:]RE:GOTO 500
1040 GOTO 1010
1100 PRINT :PRINT "{rvrs on}P{rvrs off}ITCH = ";:INPUT A
1110 IF A<0 OR A>255 THEN 1100
1120 POKE 39439,A:GOTO 500
1200 PRINT:PRINT "{rvrs on}S{rvrs off}PEED = ";:INPUT A
1210 IF A<0 OR A>255 THEN 1200
1220 POKE 39438,A:GOTO 500
1300 PRINT :PRINT "{rvrs on}T{rvrs off}HROAT = ";:INPUT A
1310 IF A<0 OR A>255 THEN 1300
1320 POKE 38881,A:SYS 38882:GOTO 500
1400 PRINT :PRINT "{rvrs on}M{rvrs off}OUTH = ";:INPUT A
1410 IF A<0 OR A>255 THEN 1400
1420 POKE 38880,A:SYS 38882:GOTO 500
1500 PRINT:PRINT "  LIGHTS   O{rvrs on}N{rvrs off}  O{rvrs on}F{rvrs off}F"
1510 GET A$:IF A$="" THEN 1510
1520 IF A$="F" OR A$="{$c6}" THEN:]LI 0:GOTO 500
1530 IF A$="N" OR A$="{$ce}" THEN:]LI 1:GOTO 500
1540 GOTO 1510
1600 ]PI 64:]SP 72:]KN 128,128:]LI 0:GOTO 500
